/*
 * Copyright 2020 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */


import androidx.build.BundleInsideHelper
import androidx.build.Publish
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    id("AndroidXPlugin")
    id("com.android.library")
    id("kotlin-android")
    id("kotlin-kapt")
}

apply from: "../camera-camera2-pipe/dependencies.gradle"

BundleInsideHelper.forInsideAar(
    project,
    /* from = */ "androidx.camera.camera2.pipe",
    /* to =   */ "androidx.camera.camera2.pipe"
)

configurations {
    bundleInside {
        attributes {
            attribute(Attribute.of("com.android.build.api.attributes.BuildTypeAttr", String), "release")
            attribute(Attribute.of("artifactType", String), "jar")
        }
        transitive = false
    }
}


dependencies {
    implementation("androidx.core:core:1.3.2")
    implementation("androidx.concurrent:concurrent-listenablefuture-callback:1.0.0-beta01")
    bundleInside(project(path: ":camera:camera-camera2-pipe"))

    // Classes and types that are needed at compile & runtime
    api("androidx.annotation:annotation:1.1.0")
    api(project(":camera:camera-core"))

    // Classes and types that are only needed at runtime
    implementation("androidx.lifecycle:lifecycle-livedata-ktx:2.3.1")
    implementation("androidx.concurrent:concurrent-futures:1.0.0")
    implementation(libs.kotlinStdlib)
    implementation(project(":concurrent:concurrent-futures-ktx"))

    // Since we jarjar CameraPipe, include the transitive dependencies as implementation
    implementation(CAMERA_PIPE_DEPS.API)
    implementation(CAMERA_PIPE_DEPS.IMPLEMENTATION)

    kapt(libs.daggerCompiler)

    testImplementation(libs.testCore)
    testImplementation(libs.testRunner)
    testImplementation(libs.junit)
    testImplementation(libs.truth)
    testImplementation(libs.mockitoCore4)
    testImplementation(libs.mockitoKotlin4)
    testImplementation(libs.robolectric)
    testImplementation(libs.kotlinCoroutinesTest)
    testImplementation(project(":camera:camera-camera2-pipe-testing"))
    testImplementation(project(":camera:camera-testing"))
    testImplementation(project(":internal-testutils-ktx"))
    testImplementation(project(":internal-testutils-truth"))
    testImplementation("androidx.exifinterface:exifinterface:1.0.0")
    testImplementation("androidx.lifecycle:lifecycle-runtime-testing:2.3.1")
    testImplementation(project(":camera:camera-video"))

    androidTestImplementation(libs.multidex)
    androidTestImplementation(libs.testExtJunit)
    androidTestImplementation(libs.testRunner)
    androidTestImplementation(libs.kotlinCoroutinesAndroid)
    androidTestImplementation(libs.kotlinStdlib)
    androidTestImplementation(libs.truth)
    androidTestImplementation(project(":annotation:annotation-experimental"))
    androidTestImplementation(project(":camera:camera-lifecycle"))
    androidTestImplementation(project(":camera:camera-testing"))
    androidTestImplementation(project(":camera:camera-video"))
    androidTestImplementation(project(":concurrent:concurrent-futures-ktx"))
    androidTestImplementation(project(":internal-testutils-truth"))
    androidTestImplementation("androidx.test.espresso:espresso-core:3.3.0")
}

android {
    defaultConfig {
        multiDexEnabled = true
    }
    lintOptions {
        enable 'CameraXQuirksClassDetector'
    }
    namespace "androidx.camera.camera2.pipe.integration"
}

kapt {
    javacOptions {
        option("-Adagger.fastInit=enabled")
        option("-Adagger.fullBindingGraphValidation=ERROR")
    }
}

androidx {
    name = "Jetpack Camera Camera Pipe Integration Library"
    publish = Publish.SNAPSHOT_AND_RELEASE
    mavenVersion = LibraryVersions.CAMERA_PIPE
    inceptionYear = "2020"
    description = "A CameraPipe implementation of CameraX, a library providing a consistent and " +
            "reliable camera foundation that enables great camera driven experiences across all " +
            "of Android."
}