/*
 * Copyright 2018 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

import static androidx.build.dependencies.DependenciesKt.*
import androidx.build.LibraryGroups
import androidx.build.LibraryVersions
import androidx.build.Publish

plugins {
    id("AndroidXPlugin")
    id("com.android.library")
    id("org.jetbrains.kotlin.android")
}

dependencies {
    api(project(":activity:activity"))
    api("androidx.core:core-ktx:1.1.0") {
        because 'Mirror activity dependency graph for -ktx artifacts'
    }
    api(project(":lifecycle:lifecycle-runtime-ktx")) {
        because 'Mirror activity dependency graph for -ktx artifacts'
    }
    api(project(":lifecycle:lifecycle-viewmodel-ktx"))
    api(project(":savedstate:savedstate-ktx")) {
        because 'Mirror activity dependency graph for -ktx artifacts'
    }
    api(KOTLIN_STDLIB)

    androidTestImplementation(project(":lifecycle:lifecycle-runtime-testing"))
    androidTestImplementation(JUNIT)
    androidTestImplementation(TRUTH)
    androidTestImplementation(ANDROIDX_TEST_EXT_JUNIT)
    androidTestImplementation(ANDROIDX_TEST_CORE)
    androidTestImplementation(ANDROIDX_TEST_RUNNER)
    androidTestImplementation(ANDROIDX_TEST_RULES)
    androidTestImplementation project(':internal-testutils-runtime'), {
        exclude group: 'androidx.activity', module: 'activity'
    }
}

androidx {
    name = "Activity Kotlin Extensions"
    publish = Publish.SNAPSHOT_AND_RELEASE
    mavenGroup = LibraryGroups.ACTIVITY
    inceptionYear = "2018"
    description = "Kotlin extensions for 'activity' artifact"
}