/*
 * Copyright (C) 2016 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

import static androidx.build.dependencies.DependenciesKt.*
import androidx.build.LibraryGroups
import androidx.build.LibraryVersions
import androidx.build.AndroidXExtension
import androidx.build.Publish

plugins {
    id("AndroidXPlugin")
    id("com.android.library")
    id("kotlin-android")
}

dependencies {
    api("androidx.annotation:annotation:1.1.0")
    api("androidx.lifecycle:lifecycle-runtime-ktx:2.3.1")
    api("androidx.lifecycle:lifecycle-viewmodel-ktx:2.3.1")
    api("androidx.savedstate:savedstate:1.0.0")
    api("androidx.lifecycle:lifecycle-viewmodel-savedstate:2.3.1")
    implementation("androidx.core:core-ktx:1.1.0")
    implementation("androidx.collection:collection-ktx:1.1.0")

    api(KOTLIN_STDLIB)
    testImplementation(JUNIT)
    testImplementation(MOCKITO_CORE)
    testImplementation(TRUTH)
    testImplementation(KOTLIN_STDLIB)

    androidTestImplementation(ANDROIDX_TEST_EXT_JUNIT)
    androidTestImplementation(ANDROIDX_TEST_CORE)
    androidTestImplementation(ANDROIDX_TEST_RUNNER)
    androidTestImplementation(ESPRESSO_CORE)
    androidTestImplementation(TRUTH)
    androidTestImplementation(MOCKITO_CORE, excludes.bytebuddy)
    androidTestImplementation(DEXMAKER_MOCKITO, excludes.bytebuddy)
    androidTestImplementation(KOTLIN_STDLIB)
}

//used by testImplementation safe-args-generator
android.libraryVariants.all { variant ->
    def name = variant.name
    def suffix = name.capitalize()
    project.tasks.register("jar${suffix}", Copy).configure {
        dependsOn("assemble$suffix")
        from(zipTree("${project.buildDir}/outputs/aar/navigation-common-${name}.aar")) {
            include("classes.jar")
        }
        destinationDir(new File(project.buildDir, "libJar"))
    }
}

androidx {
    name = "Android Navigation Common"
    publish = Publish.SNAPSHOT_AND_RELEASE
    mavenGroup = LibraryGroups.NAVIGATION
    inceptionYear = "2017"
    description = "Android Navigation-Common"
}