third_party/abseil-cpp/abseil-cpp.gni

# Copyright 2023 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pw_build/target_types.gni")

declare_args() {
  # If compiling tests with Abseil C++, this variable is set to the path to the
  # Abseil C++ installation. When set, a pw_source_set for the Abseil C++ library
  # is created at "$dir_pw_third_party/abseil-cpp".
  dir_pw_third_party_abseil_cpp = ""
}

# Like `pw_source_set`, but with modified configs for building Abseil C++.
template("abseil_cpp_source_set") {
  pw_source_set(target_name) {
    configs = []
    public_configs = []
    remove_configs = []
    forward_variables_from(invoker, "*")
    configs += [ "$dir_pw_third_party/abseil-cpp:absl_config" ]
    public_configs += [ "$dir_pw_third_party/abseil-cpp:absl_public_config" ]
    remove_configs += [ "$dir_pw_fuzzer:instrumentation" ]
  }
}