compose/ui/ui-test-junit4/build.gradle

/*
 * Copyright 2019 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

/**
 * This file was created using the `create_project.py` script located in the
 * `<AndroidX root>/development/project-creator` directory.
 *
 * Please use that script when creating a new project, rather than copying an existing project and
 * modifying its settings.
 */

import androidx.build.KotlinTarget
import androidx.build.LibraryType
import androidx.build.PlatformIdentifier

plugins {
    id("AndroidXPlugin")
    id("com.android.library")
    id("AndroidXComposePlugin")
}

androidXMultiplatform {
    android()
    jvmStubs()

    defaultPlatform(PlatformIdentifier.ANDROID)

    sourceSets {
        commonMain {
            dependencies {
                api(project(":compose:ui:ui-test"))
                implementation("androidx.annotation:annotation:1.8.1")
                implementation(libs.kotlinStdlib)
                implementation(libs.kotlinCoroutinesCore)
                implementation(libs.kotlinCoroutinesTest)
            }
        }

        commonTest {
            dependencies {
            }
        }

        jvmMain {
            dependsOn(commonMain)
            dependencies {
                api(libs.junit)
            }
        }

        androidMain {
            dependsOn(jvmMain)
            dependencies {
                api("androidx.activity:activity:1.2.1")
                api("androidx.test.ext:junit:1.1.5")
                implementation("androidx.activity:activity-compose:1.3.0")
                implementation("androidx.compose.runtime:runtime-saveable:1.6.0")
                implementation("androidx.lifecycle:lifecycle-common:2.5.1")
                implementation("androidx.lifecycle:lifecycle-runtime:2.5.1")
                implementation("androidx.test:core:1.5.0")
                implementation("androidx.test:monitor:1.6.1")
            }
        }

        jvmStubsMain {
            dependsOn(jvmMain)
            dependencies {
                implementation(libs.truth)
            }
        }

        androidInstrumentedTest {
            dependsOn(commonTest)
            dependencies {
                implementation(project(":compose:animation:animation"))
                implementation(project(":compose:test-utils"))
                implementation(project(":compose:material:material"))
                implementation("androidx.fragment:fragment-testing:1.4.1")
                implementation(libs.testRules)
                implementation(libs.testRunner)
                implementation(libs.truth)
                implementation(libs.mockitoCore)
                implementation(libs.dexmakerMockito)
                implementation(libs.mockitoKotlin)
            }
        }

        androidUnitTest {
            dependsOn(commonTest)
            dependencies {
                implementation(project(":compose:animation:animation-core"))
                implementation(project(":compose:material:material"))
                implementation(project(":compose:test-utils"))
                implementation(libs.truth)
                implementation(libs.robolectric)
            }
        }
    }
}


android {
    compileSdk = 35
    lintOptions {
        disable("InvalidPackage")
    }
    namespace = "androidx.compose.ui.test.junit4"
}

androidx {
    name = "Compose Testing for JUnit4"
    type = LibraryType.PUBLISHED_KOTLIN_ONLY_TEST_LIBRARY
    inceptionYear = "2020"
    description = "Compose testing integration with JUnit4"
    legacyDisableKotlinStrictApiMode = true
    metalavaK2UastEnabled = false
    kotlinTarget = KotlinTarget.KOTLIN_1_9
}