viewpager2/integration-tests/targetsdk-tests/build.gradle

/*
 * Copyright 2021 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

plugins {
    id("AndroidXPlugin")
    id("com.android.library")
    id("kotlin-android")
}

android {
    compileSdk = 35
    flavorDimensions = ["targetSdk"]
    productFlavors {
        targetSdk29 {
            dimension "targetSdk"
        }
        targetSdk30 {
            dimension "targetSdk"
        }
        targetSdkLatest {
            dimension "targetSdk"
            // Default is set to latest
        }
    }
    namespace = "androidx.viewpager2.integration.targestsdktests"
}

androidComponents {
    beforeVariants(selector().withFlavor("targetSdk", "targetSdk29")) { variant ->
        variant.androidTest.targetSdk = 29
    }
    beforeVariants(selector().withFlavor("targetSdk", "targetSdk30")) { variant ->
        variant.androidTest.targetSdk = 30
    }
}

dependencies {
    androidTestImplementation(project(":viewpager2:viewpager2"))
    androidTestImplementation("androidx.activity:activity-ktx:1.3.1")
    androidTestImplementation("androidx.fragment:fragment-ktx:1.3.6")
    androidTestImplementation(libs.testRunner)
    androidTestImplementation(libs.testMonitor)
    androidTestImplementation(libs.testExtJunit)
}