core/build.gradle

import static androidx.build.dependencies.DependenciesKt.*
import androidx.build.LibraryGroups
import androidx.build.LibraryVersions

plugins {
    id("SupportAndroidLibraryPlugin")
}

dependencies {
    api(project(":annotation"))
    implementation("androidx.collection:collection:1.0.0")
    api(ARCH_LIFECYCLE_RUNTIME, libs.exclude_annotations_transitive)
    api(project(":versionedparcelable"))
    api(GUAVA_LISTENABLE_FUTURE)
    implementation("androidx.concurrent:concurrent-futures:1.0.0-alpha02")

    androidTestImplementation(TEST_EXT_JUNIT)
    androidTestImplementation(TEST_CORE)
    androidTestImplementation(TEST_RUNNER)
    androidTestImplementation(TEST_RULES)
    androidTestImplementation(ESPRESSO_CORE, libs.exclude_for_espresso)
    androidTestImplementation(MOCKITO_CORE, libs.exclude_bytebuddy) // DexMaker has it"s own MockMaker
    androidTestImplementation(DEXMAKER_MOCKITO, libs.exclude_bytebuddy) // DexMaker has it"s own MockMaker
    androidTestImplementation project(':internal-testutils'), {
        exclude group: 'androidx.core', module: 'core'
    }
    annotationProcessor(project(":versionedparcelable-annotation"))
}

android {
    sourceSets {
        main.res.srcDirs 'res', 'res-public'
    }

    aaptOptions {
        noCompress 'ttf'
    }

    buildTypes.all {
        consumerProguardFiles 'proguard-rules.pro'
    }
}

supportLibrary {
    name = "Android Support Library compat"
    publish = true
    mavenVersion = LibraryVersions.CORE
    mavenGroup = LibraryGroups.CORE
    inceptionYear = "2015"
    description = "The Support Library is a static library that you can add to your Android application in order to use APIs that are either not available for older platform versions or utility APIs that aren\'t a part of the framework APIs. Compatible on devices running API 14 or later."
    failOnUncheckedWarnings = false
    failOnDeprecationWarnings = false
}