wear/tiles/tiles-renderer/build.gradle

/*
 * Copyright 2021 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

/**
 * This file was created using the `create_project.py` script located in the
 * `<AndroidX root>/development/project-creator` directory.
 *
 * Please use that script when creating a new project, rather than copying an existing project and
 * modifying its settings.
 */

import androidx.build.LibraryType
import androidx.build.LibraryType

plugins {
    id("AndroidXPlugin")
    id("com.android.library")
    id("kotlin-android")
    id("com.google.protobuf")
}

dependencies {
    api(libs.jspecify)
    api("androidx.annotation:annotation:1.8.1")
    api(libs.guavaListenableFuture)

    implementation "androidx.concurrent:concurrent-futures:1.1.0"
    implementation "androidx.concurrent:concurrent-futures-ktx:1.1.0"
    implementation("androidx.core:core:1.7.0")
    implementation "androidx.wear:wear:1.2.0"

    api(project(":wear:protolayout:protolayout"))
    implementation(project(":wear:protolayout:protolayout-expression-pipeline"))
    implementation(project(":wear:protolayout:protolayout-renderer"))
    implementation(project(":wear:tiles:tiles"))
    implementation(project(":wear:tiles:tiles-proto"))
    implementation(libs.kotlinCoroutinesCore)
    implementation(libs.kotlinCoroutinesAndroid)

    androidTestImplementation(project(":test:screenshot:screenshot"))
    androidTestImplementation(libs.testExtJunit)
    androidTestImplementation(libs.testCore)
    androidTestImplementation(libs.testRunner)
    androidTestImplementation(libs.testRules)
    androidTestImplementation(libs.protobuf)

    testImplementation(libs.testExtJunit)
    testImplementation(libs.testExtTruth)
    testImplementation(libs.testCore)
    testImplementation(libs.testRunner)
    testImplementation(libs.testRules)
    testImplementation(libs.kotlinCoroutinesTest)
    testImplementation(libs.robolectric)
    testImplementation(libs.mockitoCore4)
    testImplementation(libs.mockitoKotlin4)
    testImplementation(libs.truth)
}

android {
    defaultConfig {
        minSdk = 26
    }

    buildTypes.configureEach {
        consumerProguardFiles "proguard-rules.pro"
    }

    // Use Robolectric 4.+
    testOptions.unitTests.includeAndroidResources = true

    namespace = "androidx.wear.tiles.renderer"
}

protobuf {
    generateProtoTasks {
        all().configureEach { task ->
            task.builtins {
                java {
                    // AndroidXPlugin defaults to lite as most projects should use that library,
                    // however TileRendererGoldenTest relies on full proto library.
                    options.remove("lite")
                }
            }
        }
    }
}

androidx {
    name = "Android Wear Tiles Renderer"
    type = LibraryType.PUBLISHED_LIBRARY
    inceptionYear = "2021"
    description = "Android Wear Tiles Renderer components. These components can be used to parse " +
            "and render an already constructed Wear Tile."
    legacyDisableKotlinStrictApiMode = true
    addGoldenImageAssets()
}