hilt/hilt-compiler/build.gradle

/*
 * Copyright 2020 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

import androidx.build.LibraryType
import androidx.build.SdkHelperKt
import androidx.build.SupportConfig

plugins {
    id("AndroidXPlugin")
    id("kotlin")
    id("kotlin-kapt")
}

dependencies {
    implementation(libs.kotlinStdlib)
    compileOnly(libs.autoServiceAnnotations)
    kapt(libs.autoService)
    compileOnly(libs.gradleIncapHelper)
    kapt(libs.gradleIncapHelperProcessor)
    implementation(libs.autoCommon)
    implementation(libs.javapoet)

    testImplementation(project(":hilt:hilt-common"))
    testImplementation(libs.junit)
    testImplementation(libs.truth)
    testImplementation(libs.googleCompileTesting)
    testImplementation(libs.hiltCore)
    testImplementation(fileTree(
            dir: provider {
                // Replace with AGP API once it is added b/228109260
                // Wrapping in a provider as a workaround as we access buildDir before this project is configured
                "${new File(project(":hilt:hilt-work").buildDir, "libJar")}"
            },
            include : "*.jar"))
    testImplementation(fileTree(
            dir: "${SdkHelperKt.getSdkPath(project)}/platforms/$SupportConfig.COMPILE_SDK_VERSION/",
            include : "android.jar"))
}

tasks.named("compileKotlin").configure {
    dependsOn(":hilt:hilt-work:jarRelease")
}

androidx {
    name = "AndroidX Hilt Extension Compiler"
    type = LibraryType.COMPILER_PLUGIN
    mavenVersion = LibraryVersions.HILT
    mavenGroup = LibraryGroups.HILT
    inceptionYear = "2020"
    description = "AndroidX Hilt Extension Compiler"
}