tv/integration-tests/presentation/build.gradle

/*
 * Copyright (C) 2022 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

/**
 * This file was created using the `create_project.py` script located in the
 * `<AndroidX root>/development/project-creator` directory.
 *
 * Please use that script when creating a new project, rather than copying an existing project and
 * modifying its settings.
 */
import androidx.build.LibraryType

plugins {
    id("AndroidXPlugin")
    id("com.android.application")
    id("AndroidXComposePlugin")
    id("org.jetbrains.kotlin.android")
}

dependencies {
    implementation(libs.kotlinStdlib)

    def composeVersion = "1.6.7"

    implementation("androidx.activity:activity-compose:1.9.0")
    implementation("androidx.appcompat:appcompat:1.6.1")
    implementation("androidx.compose.animation:animation:$composeVersion")
    implementation("androidx.compose.foundation:foundation-layout:$composeVersion")
    implementation("androidx.compose.material:material-icons-core:$composeVersion")
    implementation("androidx.compose.material:material-icons-extended:$composeVersion")
    implementation("androidx.compose.material3:material3:1.2.1")
    implementation("androidx.compose.runtime:runtime:$composeVersion")
    implementation("androidx.compose.ui:ui:$composeVersion")
    implementation("androidx.navigation:navigation-runtime:2.7.7")
    implementation("androidx.profileinstaller:profileinstaller:1.3.1")
    implementation(project(":tv:tv-foundation"))
    implementation(project(":tv:tv-material"))
}

androidx {
    name = "TV-Compose Test App"
    type = LibraryType.SAMPLES
    mavenVersion = LibraryVersions.TV
    inceptionYear = "2022"
    description = "Test application for TV libraries"
}

android {
    defaultConfig {
        minSdkVersion 28
    }

    buildTypes {
        release {
            minifyEnabled true
            shrinkResources true
            proguardFiles getDefaultProguardFile('proguard-android.txt')
            signingConfig signingConfigs.debug
        }
    }
    namespace "androidx.tv.integration.presentation"
}

// Workaround for https://github.com/gradle/gradle/issues/19882
configurations.all {
    resolutionStrategy.dependencySubstitution {
        substitute(module("androidx.lifecycle:lifecycle-common-java8:")).
                using project(":lifecycle:lifecycle-common-java8")
        substitute(module("androidx.lifecycle:lifecycle-livedata-core:")).
                using project(":lifecycle:lifecycle-livedata-core")
        substitute(module("androidx.lifecycle:lifecycle-runtime:")).
                using project(":lifecycle:lifecycle-runtime")
        substitute(module("androidx.lifecycle:lifecycle-runtime-ktx:")).
                using project(":lifecycle:lifecycle-runtime-ktx")
        substitute(module("androidx.lifecycle:lifecycle-viewmodel:")).
                using project(":lifecycle:lifecycle-viewmodel")
        substitute(module("androidx.lifecycle:lifecycle-viewmodel-ktx:")).
                using project(":lifecycle:lifecycle-viewmodel-ktx")
        substitute(module("androidx.lifecycle:lifecycle-viewmodel-savedstate:")).
                using project(":lifecycle:lifecycle-viewmodel-savedstate")
    }
}