ink/ink-storage/build.gradle

/*
 * Copyright (C) 2025 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

import androidx.build.SoftwareType
import androidx.build.PlatformIdentifier

plugins {
    id("AndroidXPlugin")
}

androidXMultiplatform {
    jvm()
    androidLibrary {
        namespace = "androidx.ink.storage"
        compileSdk = 35
    }

    defaultPlatform(PlatformIdentifier.JVM)

    sourceSets {
        commonMain {
            dependencies {
                api(libs.kotlinStdlib)
            }
        }

        jvmAndroidMain {
            dependsOn(commonMain)
            dependencies {
                implementation(project(":ink:ink-brush"))
                implementation(project(":ink:ink-strokes"))
                implementation(project(":ink:ink-nativeloader"))
            }
        }

        jvmAndroidTest {
            dependsOn(commonTest)
            dependencies {
                implementation(libs.junit)
                implementation(libs.kotlinTest)
                implementation(libs.truth)
                implementation(project(":ink:ink-brush"))
                implementation(project(":ink:ink-strokes"))
            }
        }

        jvmMain {
            dependsOn(jvmAndroidMain)
        }

        jvmTest {
            dependsOn(jvmAndroidTest)
        }

        androidMain {
            dependsOn(jvmAndroidMain)
	    dependencies {
                implementation(project(":ink:ink-rendering"))
	    }
        }

        androidInstrumentedTest {
            // JVM tests use java.util.Base64 API which is only available on
            // Android API 26+, so just run those tests in the JVM environment.
            // dependsOn(jvmAndroidTest)
            dependencies {
                implementation(libs.testExtJunit)
                implementation(libs.testRules)
                implementation(libs.testRunner)
                implementation(libs.espressoCore)
                implementation(libs.junit)
                implementation(libs.kotlinTest)
                implementation(libs.truth)
            }
        }
    }
}

androidx {
    name = "Ink Storage"
    type = SoftwareType.PUBLISHED_LIBRARY
    inceptionYear = "2025"
    description = "Efficiently store and retrieve Ink strokes"
}