compose/foundation/foundation-layout/build.gradle

/*
 * Copyright 2019 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */


import androidx.build.AndroidXUiPlugin
import androidx.build.LibraryGroups
import androidx.build.Publish

import static androidx.build.dependencies.DependenciesKt.*

plugins {
    id("AndroidXPlugin")
    id("com.android.library")
    id("AndroidXUiPlugin")
}

AndroidXUiPlugin.applyAndConfigureKotlinPlugin(project)

dependencies {
    kotlinPlugin project(":compose:compiler:compiler")

    if(!AndroidXUiPlugin.isMultiplatformEnabled(project)) {
        /*
         * When updating dependencies, make sure to make the an an analogous update in the
         * corresponding block below
         */

        api "androidx.annotation:annotation:1.1.0"
        api project(":compose:ui:ui")

        implementation project(":compose:runtime:runtime")
        implementation project(":compose:ui:ui-util")
        implementation(CONSTRAINT_LAYOUT_CORE)
        implementation(KOTLIN_STDLIB_COMMON)

        testImplementation(ANDROIDX_TEST_RULES)
        testImplementation(ANDROIDX_TEST_RUNNER)
        testImplementation(JUNIT)

        androidTestImplementation project(":compose:foundation:foundation")
        androidTestImplementation project(":compose:ui:ui-test-junit4")
        androidTestImplementation(ANDROIDX_TEST_RULES)
        androidTestImplementation(ANDROIDX_TEST_RUNNER)
        androidTestImplementation(JUNIT)
        androidTestImplementation(TRUTH)
    }
}

if(AndroidXUiPlugin.isMultiplatformEnabled(project)) {
    kotlin {
        android()
        jvm("desktop")

        /*
         * When updating dependencies, make sure to make the an an analogous update in the
         * corresponding block above
         */
        sourceSets {
            commonMain.dependencies {
                implementation(KOTLIN_STDLIB_COMMON)

                api project(":compose:ui:ui")
                implementation project(":compose:runtime:runtime")
                implementation project(":compose:ui:ui-util")
            }

            androidMain.dependencies {
                api "androidx.annotation:annotation:1.1.0"
                implementation(CONSTRAINT_LAYOUT_CORE)
            }

            desktopMain.dependencies {
                implementation(KOTLIN_STDLIB)
            }

            androidTest.dependencies {
                implementation(ANDROIDX_TEST_RULES)
                implementation(ANDROIDX_TEST_RUNNER)
                implementation(JUNIT)
            }

            androidAndroidTest.dependencies {
                implementation project(":compose:foundation:foundation")
                implementation project(":compose:ui:ui-test-junit4")

                implementation(ANDROIDX_TEST_RULES)
                implementation(ANDROIDX_TEST_RUNNER)
                implementation(JUNIT)
                implementation(TRUTH)
            }
        }
    }
}

androidx {
    name = "Compose Layouts"
    publish = Publish.SNAPSHOT_AND_RELEASE
    mavenGroup = LibraryGroups.Compose.FOUNDATION
    inceptionYear = "2019"
    description = "Compose layout implementations"
    legacyDisableKotlinStrictApiMode = true
}