lifecycle/lifecycle-viewmodel/build.gradle

/*
 * Copyright 2017 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

/**
 * This file was created using the `createProject` gradle task (./gradlew createProject)
 *
 * Please use the task when creating a new project, rather than copying an existing project and
 * modifying its settings.
 */

import androidx.build.SoftwareType
import androidx.build.PlatformIdentifier
import org.jetbrains.kotlin.gradle.plugin.KotlinPlatformType
import org.jetbrains.kotlin.konan.target.Family

plugins {
    id("AndroidXPlugin")
}

androidXMultiplatform {
    androidLibrary {
        namespace = "androidx.lifecycle.viewmodel"
        optimization {
            it.consumerKeepRules.publish = true
            it.consumerKeepRules.files.add(new File("proguard-rules.pro"))
        }
        androidResources.enable = true
    }
    desktop()
    mac()
    linux()
    ios()
    watchos()
    tvos()
    mingwX64()
    js()
    wasmJs()

    defaultPlatform(PlatformIdentifier.ANDROID)

    sourceSets {
        configureEach {
            languageSettings.optIn("kotlin.contracts.ExperimentalContracts")
        }

        commonMain.dependencies {
            api("androidx.annotation:annotation:1.9.1")
            api(libs.kotlinCoroutinesCore)
            implementation("androidx.collection:collection:1.5.0")
        }

        commonTest.dependencies {
            implementation(project(":kruth:kruth"))
            implementation(libs.kotlinTest)
            implementation(libs.kotlinCoroutinesTest)
        }

        jvmAndAndroidTest.dependencies {
            implementation(libs.junit)
        }

        androidMain.dependencies {
            api(libs.kotlinCoroutinesAndroid)
            implementation("androidx.core:core-viewtree:1.0.0")
        }

        androidHostTest.dependencies {
            implementation(libs.mockitoCore4)
        }

        androidDeviceTest.dependencies {
            implementation("androidx.core:core-ktx:1.2.0")
            implementation(libs.testExtJunit)
            implementation(libs.testCore)
            implementation(libs.testRunner)
        }

        nativeMain.dependencies {
            implementation(libs.atomicFu)
        }

        webTest.dependencies {
            implementation("org.jetbrains.kotlinx:kotlinx-coroutines-core:1.9.0")
            implementation("org.jetbrains.kotlinx:kotlinx-coroutines-test:1.9.0")
        }
    }
}

dependencies {
    constraints {
        // Prevents symbols duplication with old versions of JetBrains' fork.
        // Starting with version 2.9.5, this module is published as empty artifact with dependency
        // to this androidx module.
        commonMainImplementation("org.jetbrains.androidx.lifecycle:lifecycle-viewmodel:2.9.5") {
            because "prevents symbols duplication"
        }
    }
}

androidx {
    name = "Lifecycle ViewModel"
    type = SoftwareType.PUBLISHED_LIBRARY
    inceptionYear = "2017"
    description = "Android Lifecycle ViewModel"
}