testutils/testutils-navigation/build.gradle

/*
 * Copyright 2018 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

/**
 * This file was created using the `createProject` gradle task (./gradlew createProject)
 *
 * Please use the task when creating a new project, rather than copying an existing project and
 * modifying its settings.
 */

import androidx.build.PlatformIdentifier
import androidx.build.SoftwareType
import com.android.build.api.dsl.KotlinMultiplatformAndroidHostTestCompilation

plugins {
    id("AndroidXPlugin")
}

androidXMultiplatform {
    androidLibrary {
        namespace = "androidx.testutils.navigation"
        androidResources.enable = true
        compilations.withType(KotlinMultiplatformAndroidHostTestCompilation) {
            it.returnDefaultValues = true
        }
    }
    desktop()
    linux()
    mac()
    ios()
    js()
    wasmJs()

    defaultPlatform(PlatformIdentifier.ANDROID)

    sourceSets {
        commonMain.dependencies {
            api(project(":navigation:navigation-common"))
        }
        commonTest.dependencies {
            implementation(libs.kotlinTest)
            implementation(libs.kotlinCoroutinesTest)
            implementation(project(":navigation:navigation-testing"))
            implementation(project(":kruth:kruth"))
        }
        create("androidTest").dependencies {
            implementation("androidx.arch.core:core-testing:2.1.0")
        }
        androidDeviceTest.dependencies {
            implementation(libs.testExtJunit)
            implementation(libs.testCore)
            implementation(libs.testRunner)
            implementation(libs.espressoCore)
        }

        androidTest.dependsOn(commonTest)
        androidHostTest.dependsOn(androidTest)
        androidDeviceTest.dependsOn(androidTest)

        create("nonAndroidMain").dependsOn(commonMain)
        desktopMain.dependsOn(nonAndroidMain)
        nativeMain.dependsOn(nonAndroidMain)
        webMain.dependsOn(nonAndroidMain)

        create("nonAndroidTest").dependsOn(commonTest)
        desktopTest.dependsOn(nonAndroidTest)
        nativeTest.dependsOn(nonAndroidTest)
        webTest.dependsOn(nonAndroidTest)
    }
}

androidx {
    type = SoftwareType.INTERNAL_TEST_LIBRARY
}