buildSrc/build.gradle.kts

/*
 * Copyright (C) 2020 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

plugins {
    alias(libs.plugins.kotlinJvm)
    `java-gradle-plugin`
}

repositories {
    // For CI builds, it is important to use prebuilts because maven central throttles requests for
    // artifacts. The `DOWNLOAD_DEPENDENCIES` flag allows building locally in repos which do not
    // include the AndroidX prebuilts repo.
    if (System.getenv("DOWNLOAD_DEPENDENCIES") == "true") {
        mavenCentral()
        google()
    } else {
        maven("../../../prebuilts/androidx/external")
    }
}

dependencies {
    implementation(gradleApi())
    implementation(gradleKotlinDsl())
    implementation(libs.kotlinGradlePlugin)
    implementation(libs.androidGradlePlugin)
    implementation(libs.gson)
}

gradlePlugin {
    plugins {
        create("metalava-build-plugin") {
            id = "metalava-build-plugin"
            implementationClass = "com.android.tools.metalava.MetalavaBuildPlugin"
        }
        create("metalava-model-provider-plugin") {
            id = "metalava-model-provider-plugin"
            implementationClass = "com.android.tools.metalava.MetalavaModelProviderPlugin"
        }
    }
}

kotlin {
    compilerOptions {
        allWarningsAsErrors = true
    }
}